Summary


The Snom phone’s Tbook is exported with commas and double quotes. The imported .csv file must contain the same formatting.


e.g.  "","0564123456789","","active","test","test2","","","","","00.00.1899","","false","","mobile",""


When creating a phonebook in Excel and exporting it as a .csv file, it does not have the double quotes as needed.


e.g.  ,0564123456789,,active,test,test2,,,,,00.00.1899,,false,,mobile


You can run a VB macro on the spreadsheet data and export the phonebook as a comma and double quoted .csv file using the following procedure.


Instructions


1. Create or open your phonebook in Microsoft Excel.

2. Select the data to be exported by dragging your mouse from the beginning row and column to the ending row and column of the data.

 

3. Open the Visual Basic editor by pressing  Alt + F11

4. One the Visual Basic editor is open, copy and paste the following code into the editor;

Sub QuoteCommaExport()
   ' Dimension all variables.
   Dim DestFile As String
   Dim FileNum As Integer
   Dim ColumnCount As Integer
   Dim RowCount As Integer

   ' Prompt user for destination file name.
   DestFile = InputBox("Enter the destination filename" _
      & Chr(10) & "(with complete path):", "Quote-Comma Exporter")

   ' Obtain next free file handle number.
   FileNum = FreeFile()

   ' Turn error checking off.
   On Error Resume Next

   ' Attempt to open destination file for output.
   Open DestFile For Output As #FileNum

   ' If an error occurs report it and end.
   If Err <> 0 Then
      MsgBox "Cannot open filename " & DestFile
      End
   End If

   ' Turn error checking on.
   On Error GoTo 0

   ' Loop for each row in selection.
   For RowCount = 1 To Selection.Rows.Count

      ' Loop for each column in selection.
      For ColumnCount = 1 To Selection.Columns.Count

         ' Write current cell's text to file with quotation marks.
         Print #FileNum, """" & Selection.Cells(RowCount, _
            ColumnCount).Text & """";

         ' Check if cell is in last column.
         If ColumnCount = Selection.Columns.Count Then
            ' If so, then write a blank line.
            Print #FileNum,
         Else
            ' Otherwise, write a comma.
            Print #FileNum, ",";
         End If
      ' Start next iteration of ColumnCount loop.
      Next ColumnCount
   ' Start next iteration of RowCount loop.
   Next RowCount

   ' Close destination file.
   Close #FileNum
End Sub



5. Next, run the macro from the toolbar menu above.

6. You will then be prompted to enter the destination filename and complete path. You are creating the file here.


e.g. C:\Test CSV phonebook.csv


7. Open the exported .csv file in a text editor to confirm it has the proper file formatting.

8. Provision or import the newly created Tbook into your Snom phone as needed.